Help with Max scripting

[aaouviz]

Man, I suck at maxscript...

I want to make a simple "Save and then Exit" script (via toolbar button).

This is what I have, but I can't quite get it to work as intended. Any helpers out there? Many thanks!

Code: [Select]

--Original script by: aaouviz
------

macroscript SaveAndExit
category: "AAScripts"
buttonText: "Save and Exit"
tooltip: "Save and Exit"
Icon:#("AAGen_01",1)


(
saveMaxFile
)
quitmax #noprompt

[James Vella]

I assume you just want File > Save correct? Overwrite previous version?

Code: [Select]

--Original script by: aaouviz
------

macroscript SaveAndExit
category: "AAScripts"
buttonText: "Save and Exit"
tooltip: "Save and Exit"
Icon:#("AAGen_01",1)
(
        max file save
quitmax #noprompt
)


[aaouviz]

Amazing, and perfect as always James.

Thanks a million!

[James Vella]

Glad to hear its working as expected :)

[Frood]

Hi,

picked up the idea but implemented it as file menu item. Additionally, saving only happens if a save is required (no changed made to scene, relying on getSaveRequired()). Script goes to any autostart folder (usually scripts\startup). Sharing it as an alternate option.


Good Luck

[aaouviz]

Excellent!

The 'saving only happens if a save is required' seemed a bit beyond my capabilities, so I didn't bother. But this is clever of you, and I feel pleased to have I've influenced you, Frood :)

[Frood]

Yes, thanks for letting me steal that idea to use them for myself - which is my daily deed ;)


Good Luck

[aaouviz]

Hello all again,

I'm wondering if someone smarter than me can help figure this one out...

I'm trying to automate 'Unwrap UVW' to a default "Flatten: Custom" workflow. (See the picture)

I got a pretty good result with vibe coding (chatGPT) but it can't quite figure out the final, and most important component. It does everything right but doesn't get the right result (or at least not the same result as if I manually press that button).

Please see the code below and offer a suggestion if possible. Many, many thanks!

Code: [Select]

/* ===========================================================
   HELPER – unwrap one object, set channel, run Pack-Custom
   =========================================================== */
fn addUnwrapPackSingle obj mapChannel:2 =
(
    local prevSel = selection as array
    select obj

    -- Add temporary Edit Poly modifier to force full poly selection
    local epMod = Edit_Poly()
    addModifier obj epMod
    epMod.SetSelection #Face #{1..(getNumFaces obj)}
   
    -- Add the unwrap modifier
    local uMod = Unwrap_UVW()
    addModifier obj uMod
    uMod.unwrap.setMapChannel mapChannel
   
    -- Ensure full polygon selection for Unwrap as well
    uMod.unwrap.selectPolygons #{1..(uMod.unwrap.numberPolygons())}

   
    -- Set current modifier to Unwrap
    modPanel.setCurrentObject uMod
   
    -- Run Pack ► Custom
    if isProperty uMod #packNoParams then
    (
        uMod.packNoParams()
    )
    else if isProperty uMod.unwrap #packNoParams then
    (
        uMod.unwrap.packNoParams()
    )
   
    -- Optionally remove the Edit Poly modifier to clean up
    -- deleteModifier obj epMod
   
    -- Restore selection
    select prevSel
)


/* ===========================================================
   BATCH – loop through initial selection one-by-one
   =========================================================== */
fn batchUnwrapPack mapChannel:2 =
(
    local workList = for o in selection where isKindOf o GeometryClass collect o
   
    if workList.count == 0 then
    (
        messageBox "Select one or more geometry objects first!"
        return undefined
    )
   
    with undo off
    (
        for o in workList do
        (
            format ">> Unwrapping & packing : %\n" o.name
            addUnwrapPackSingle o mapChannel:mapChannel
        )
    )
   
    format "=== Finished : processed % objects ===\n" workList.count
)

/* ===========================================================
   RUN   (change the channel if you like)
   =========================================================== */
batchUnwrapPack mapChannel:2


[clemens_at]

try this:

Code: [Select]

    if isProperty uMod #packNoParams then
    (
        uMod.flattenMapNoParams()
    )
    else if isProperty uMod.unwrap #packNoParams then
    (
        uMod.unwrap.flattenMapNoParams()
also, I don't think you need the edit poly and force selection - so the simplified function:

Code: [Select]

fn addUnwrapPackSingle obj mapChannel:2 =
(
    local prevSel = selection as array
    select obj
   
    -- Add the unwrap modifier
    local uMod = Unwrap_UVW()
    addModifier obj uMod
    uMod.unwrap.setMapChannel mapChannel

    -- Set current modifier to Unwrap
    modPanel.setCurrentObject uMod
   
    -- Run Pack ► Flatten
    if isProperty uMod #packNoParams then
    (
        uMod.flattenMapNoParams()
    )
    else if isProperty uMod.unwrap #packNoParams then
    (
        uMod.unwrap.flattenMapNoParams()
    )
   
    -- Restore selection
   select prevSel
)