Chaos Corona Forum

Chaos Corona for 3ds Max => [Max] General Discussion => Topic started by: Bormax on 2019-12-06, 14:07:14

Title: Button Render selected on/off
Post by: Bormax on 2019-12-06, 14:07:14

Hello

I'd like to have button-switcher Render viewport selected object on/off, but I don't know how to make it and is it possible at all...
Could you help me with that, please.

Thanks in advanced

Title: Re: Button Render selected on/off
Post by: Frood on 2019-12-06, 17:34:03

Here you are:

Code: [Select]

macroScript ToggleCoronaRenderSelected
category:"Corona"
toolTip:"Toggle Corona render viewport selection"
icon:#("Maxscript",2)
(
callbacks.removeScripts id:#CoronaToggleRenderViewportSelection
callbacks.addScript #renderParamsChanged "updateToolbarButtons()" id:#CoronaToggleRenderViewportSelection

on isEnabled do (
return hasproperty renderers.current "renderSelected_mode"
)

on isChecked do (
if (hasproperty renderers.current "renderSelected_mode") then (
if (renderers.current.renderSelected_mode==1) then true else false
)
else return false
)

on execute do (
if (hasproperty renderers.current "renderSelected_mode") then (
animate off (
if renderers.current.renderSelected_mode!=1 then renderers.current.renderSelected_mode=1 else renderers.current.renderSelected_mode=0
)
)
)
)



Good Luck

Title: Re: Button Render selected on/off
Post by: Bormax on 2019-12-06, 17:53:01

It works perfectly!
Tank you so much, Frood!